Excel中进行表格IF函数的具体操作

Excel表格中IF函数的用法，包括基本用法、单条件、多条件表达及在数组函数中的用法和在数组函数中怎么表达多条件和单条件。今天，小编就教大家在Excel中进行表格IF函数的具体操作。

Excel中进行表格IF函数的具体步骤：

IF函数语法介绍。

1IF函数有三个参数，语法如下：

=IF(条件判断, 结果为真返回值, 结果为假返回值)

第一参数是条件判断，比如说“A1="百度"”或“21>37”这种，结果返回TRUE或FALSE。如果判断返回TRUE那么IF函数返回值是第二参数，否则返回第三参数。

如上图，

=IF(1>2,"判断真","判断假")

其中判断1大于2结果是假也就是FALSE，所以单元格返回第三参数文本“判断假”。

3第一参数在某些情况下不是用比较判断符号来判断的。Excel中将0认为是FALSE，非0值等价于TRUE。所以如下图，B1公式为：

=IF(SUM(A1:A2),"判断真","判断假")

因为A1:A2合计大于0，所以返回第二参数文本“判断真”。

IF函数参数省略用法简介：

Excel中很多函数部分参数可以省略，IF函数也一样。如下图B1的公式为：

=IF(1>2,"判断真")

省略了第三参数，则返回第三参数值时会返回FALSE。这对求满足条件最大值和最小值是由实际意义的，效果与0不同。

如果把公式改成：

=IF(1>2,"判断真",)

公式中通过第二参数后的逗号给第三参数留了位置，但是没有输入任何值，那么默认是返回0这个数字的。也就是逗号后面不输入参数默认返回值为0。

第二参数也是一样的规律，如果公式改成：

=IF(3>2,,"判断假")

第二参数位于两个逗号之间，没有输入值，则默认返回0。

如果将公式改成：

=IF(3>2,TRUE,FALSE)

则单元格会返回TRUE或FALSE这两个逻辑值结果之一。

IF普通公式单条件表达：

如下图，B2公式为：

=IF(A2>29,"不惑","小年轻")

这是IF函数单条件表达的方式，第一参数只有一个比较。

IF单条件表达可以用数轴的方式来理解。整个数轴是全体，判断为TRUE返回结果为数轴的一部分;判断为FALSE返回结果是数轴的其余所有部分，两个部分不会交叉。

IF普通公式多条件同时满足表达：

1如下图，如果A2大于29且B2是“A”则返回优秀，其余结果返回空。C2公式为：

=IF(AND(A2>29,B2="A"),"优秀","")

这里用AND()函数表达了多个判断条件，只有所有判断都返回TRUE才返回“优秀”。

大家在使用IF多条件判断的时候一定要考虑全面，不要漏掉可能!以上面的两个条件，且没有嵌套IF的例子说明。

可以将两个条件用纵横两条线交叉表示，同时满足“大于34，为A”的结果只占所有可能的四分之一，也就是其他所有可能都返回空。如果3个条件你排除的可能更多，如果再嵌套IF继续判断……

重点提醒：

如果有多个条件并且嵌套判断，一定要考虑清楚所有的情况，否则容易出现预期之外的错误返回，很多情况是漏考虑了某些情况!

IF普通公式多条件满足其一即可表达：

上面讲述了同时满足多个条件，那么满足多条件之一如何表达呢?C2输入公式：

=IF(OR(A2="A",B2>100),"合格","不合格")

IF函数中可以用OR()函数来表达满足条件之一，也就是OR()函数内的判断只要有一个返回TRUE，OR()函数整体就返回TRUE。

提醒：

使用多个OR()函数并且还有IF嵌套的情况下更要考虑所有情况，避免遗漏。

IF数组公式同时满足多条件表达：

如下图，要求A列为“A”且B列大于40的B列数据合计，C2输入公式：

=SUM(IF((A2:A4="A")*(B2:B4>40),B2:B4))

左手按住Ctrl+Shift，右手按回车运行公式。

这里(A2:A4="A")和(B2:B4>40)的判断分别返回TRUE或FALSE，其中的星号可以理解为“乘号”，在运算时TRUE相当于1，FALSE相当于0，所以只有两个返回值都是TRUE，乘积才是1;只要有一个FALSE，也就是只要有一个不满足条件，返回结果就是0。而IF第一参数中非0值相当于TRUE，所以可以达到同时满足两个条件统计的目的。

IF数组公式满足多条件表达：

如下图，要求A列为“A”或B列大于40的B列数据合计，C2输入公式：

=SUM(IF((A2:A4="A")+(B2:B4>40),B2:B4))

左手按住Ctrl+Shift，右手按回车运行公式。

把同时满足多条件的乘号改成加号就达到了“或者”的目的。因为只要有一个是TRUE，相加结果就是1，如果两个都是TRUE相加结果就是2。所以达到了判断结果相加，只要结果非0就计算B列数据合计的目的。